cachepc-linux

Fork of AMDESE/linux with modifications for CachePC side-channel attack
git clone https://git.sinitax.com/sinitax/cachepc-linux
Log | Files | Refs | README | LICENSE | sfeed.txt

hibernate_asm.S (1307B)

      1/* SPDX-License-Identifier: GPL-2.0-only */
      2/*
      3 * Hibernation support specific for mips - temporary page tables
      4 *
      5 * Copyright (C) 2009 Lemote Inc.
      6 * Author: Hu Hongbing <huhb@lemote.com>
      7 *	   Wu Zhangjin <wuzhangjin@gmail.com>
      8 */
      9#include <asm/asm-offsets.h>
     10#include <asm/regdef.h>
     11#include <asm/asm.h>
     12
     13.text
     14LEAF(swsusp_arch_suspend)
     15	PTR_LA t0, saved_regs
     16	PTR_S ra, PT_R31(t0)
     17	PTR_S sp, PT_R29(t0)
     18	PTR_S fp, PT_R30(t0)
     19	PTR_S gp, PT_R28(t0)
     20	PTR_S s0, PT_R16(t0)
     21	PTR_S s1, PT_R17(t0)
     22	PTR_S s2, PT_R18(t0)
     23	PTR_S s3, PT_R19(t0)
     24	PTR_S s4, PT_R20(t0)
     25	PTR_S s5, PT_R21(t0)
     26	PTR_S s6, PT_R22(t0)
     27	PTR_S s7, PT_R23(t0)
     28	j swsusp_save
     29END(swsusp_arch_suspend)
     30
     31LEAF(restore_image)
     32	PTR_L t0, restore_pblist
     330:
     34	PTR_L t1, PBE_ADDRESS(t0)   /* source */
     35	PTR_L t2, PBE_ORIG_ADDRESS(t0) /* destination */
     36	PTR_ADDU t3, t1, _PAGE_SIZE
     371:
     38	REG_L t8, (t1)
     39	REG_S t8, (t2)
     40	PTR_ADDIU t1, t1, SZREG
     41	PTR_ADDIU t2, t2, SZREG
     42	bne t1, t3, 1b
     43	PTR_L t0, PBE_NEXT(t0)
     44	bnez t0, 0b
     45	PTR_LA t0, saved_regs
     46	PTR_L ra, PT_R31(t0)
     47	PTR_L sp, PT_R29(t0)
     48	PTR_L fp, PT_R30(t0)
     49	PTR_L gp, PT_R28(t0)
     50	PTR_L s0, PT_R16(t0)
     51	PTR_L s1, PT_R17(t0)
     52	PTR_L s2, PT_R18(t0)
     53	PTR_L s3, PT_R19(t0)
     54	PTR_L s4, PT_R20(t0)
     55	PTR_L s5, PT_R21(t0)
     56	PTR_L s6, PT_R22(t0)
     57	PTR_L s7, PT_R23(t0)
     58	PTR_LI v0, 0x0
     59	jr ra
     60END(restore_image)