cachepc-linux

Fork of AMDESE/linux with modifications for CachePC side-channel attack
git clone https://git.sinitax.com/sinitax/cachepc-linux
Log | Files | Refs | README | LICENSE | sfeed.txt

zImage.coff.lds.S (688B)

      1/* SPDX-License-Identifier: GPL-2.0 */
      2OUTPUT_ARCH(powerpc:common)
      3ENTRY(_zimage_start_opd)
      4EXTERN(_zimage_start_opd)
      5SECTIONS
      6{
      7  .text      :
      8  {
      9    _start = .;
     10    *(.text)
     11    *(.fixup)
     12    _etext = .;
     13  }
     14  . = ALIGN(4096);
     15  .data    :
     16  {
     17    *(.rodata*)
     18    *(.data*)
     19    *(__builtin_*)
     20    *(.sdata*)
     21    *(.got2)
     22
     23    _dtb_start = .;
     24    *(.kernel:dtb)
     25    _dtb_end = .;
     26
     27    _vmlinux_start =  .;
     28    *(.kernel:vmlinux.strip)
     29    _vmlinux_end =  .;
     30
     31    _initrd_start =  .;
     32    *(.kernel:initrd)
     33    _initrd_end =  .;
     34  }
     35
     36  . = ALIGN(4096);
     37  _edata  =  .;
     38  __bss_start = .;
     39  .bss       :
     40  {
     41   *(.sbss)
     42   *(.bss)
     43  }
     44  _end = . ;
     45
     46  /DISCARD/ :
     47  {
     48    *(.comment)
     49  }
     50}