cachepc-linux

Fork of AMDESE/linux with modifications for CachePC side-channel attack
git clone https://git.sinitax.com/sinitax/cachepc-linux
Log | Files | Refs | README | LICENSE | sfeed.txt

vdso32.lds.S (3095B)

      1/* SPDX-License-Identifier: GPL-2.0 */
      2/*
      3 * This is the infamous ld script for the 32 bits vdso
      4 * library
      5 */
      6#include <asm/vdso.h>
      7#include <asm/page.h>
      8#include <asm-generic/vmlinux.lds.h>
      9
     10#ifdef __LITTLE_ENDIAN__
     11OUTPUT_FORMAT("elf32-powerpcle", "elf32-powerpcle", "elf32-powerpcle")
     12#else
     13OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
     14#endif
     15OUTPUT_ARCH(powerpc:common)
     16
     17SECTIONS
     18{
     19	PROVIDE(_vdso_datapage = . - 2 * PAGE_SIZE);
     20	. = SIZEOF_HEADERS;
     21
     22	.hash          	: { *(.hash) }			:text
     23	.gnu.hash      	: { *(.gnu.hash) }
     24	.dynsym        	: { *(.dynsym) }
     25	.dynstr        	: { *(.dynstr) }
     26	.gnu.version   	: { *(.gnu.version) }
     27	.gnu.version_d 	: { *(.gnu.version_d) }
     28	.gnu.version_r 	: { *(.gnu.version_r) }
     29
     30	.note		: { *(.note.*) }		:text	:note
     31
     32	. = ALIGN(16);
     33	.text		: {
     34		*(.text .stub .text.* .gnu.linkonce.t.* __ftr_alt_*)
     35	}		      	      			:text
     36	PROVIDE(__etext = .);
     37	PROVIDE(_etext = .);
     38	PROVIDE(etext = .);
     39
     40	. = ALIGN(8);
     41	VDSO_ftr_fixup_start = .;
     42	__ftr_fixup	: { *(__ftr_fixup) }
     43	VDSO_ftr_fixup_end = .;
     44
     45	. = ALIGN(8);
     46	VDSO_mmu_ftr_fixup_start = .;
     47	__mmu_ftr_fixup	: { *(__mmu_ftr_fixup) }
     48	VDSO_mmu_ftr_fixup_end = .;
     49
     50	. = ALIGN(8);
     51	VDSO_lwsync_fixup_start = .;
     52	__lwsync_fixup	: { *(__lwsync_fixup) }
     53	VDSO_lwsync_fixup_end = .;
     54
     55#ifdef CONFIG_PPC64
     56	. = ALIGN(8);
     57	VDSO_fw_ftr_fixup_start = .;
     58	__fw_ftr_fixup	: { *(__fw_ftr_fixup) }
     59	VDSO_fw_ftr_fixup_end = .;
     60#endif
     61
     62	/*
     63	 * Other stuff is appended to the text segment:
     64	 */
     65	.rodata		: { *(.rodata .rodata.* .gnu.linkonce.r.*) }
     66	.rodata1	: { *(.rodata1) }
     67
     68	.eh_frame_hdr	: { *(.eh_frame_hdr) }		:text	:eh_frame_hdr
     69	.eh_frame	: { KEEP (*(.eh_frame)) }	:text
     70	.gcc_except_table : { *(.gcc_except_table) }
     71	.fixup		: { *(.fixup) }
     72
     73	.dynamic	: { *(.dynamic) }		:text	:dynamic
     74	.got		: { *(.got) }			:text
     75	.plt		: { *(.plt) }
     76
     77	_end = .;
     78	__end = .;
     79	PROVIDE(end = .);
     80
     81	STABS_DEBUG
     82	DWARF_DEBUG
     83	ELF_DETAILS
     84
     85	/DISCARD/	: {
     86		*(.note.GNU-stack)
     87		*(.data .data.* .gnu.linkonce.d.* .sdata*)
     88		*(.bss .sbss .dynbss .dynsbss)
     89		*(.got1)
     90	}
     91}
     92
     93/*
     94 * Very old versions of ld do not recognize this name token; use the constant.
     95 */
     96#define PT_GNU_EH_FRAME	0x6474e550
     97
     98/*
     99 * We must supply the ELF program headers explicitly to get just one
    100 * PT_LOAD segment, and set the flags explicitly to make segments read-only.
    101 */
    102PHDRS
    103{
    104	text		PT_LOAD FILEHDR PHDRS FLAGS(5);	/* PF_R|PF_X */
    105	dynamic		PT_DYNAMIC FLAGS(4);		/* PF_R */
    106	note		PT_NOTE FLAGS(4);		/* PF_R */
    107	eh_frame_hdr	PT_GNU_EH_FRAME;
    108}
    109
    110/*
    111 * This controls what symbols we export from the DSO.
    112 */
    113VERSION
    114{
    115	VDSO_VERSION_STRING {
    116	global:
    117		__kernel_get_syscall_map;
    118		__kernel_gettimeofday;
    119		__kernel_clock_gettime;
    120		__kernel_clock_gettime64;
    121		__kernel_clock_getres;
    122		__kernel_time;
    123		__kernel_get_tbfreq;
    124		__kernel_sync_dicache;
    125		__kernel_sigtramp32;
    126		__kernel_sigtramp_rt32;
    127#if defined(CONFIG_PPC64) || !defined(CONFIG_SMP)
    128		__kernel_getcpu;
    129#endif
    130
    131	local: *;
    132	};
    133}
    134
    135/*
    136 * Make the sigreturn code visible to the kernel.
    137 */
    138VDSO_sigtramp32		= __kernel_sigtramp32;
    139VDSO_sigtramp_rt32	= __kernel_sigtramp_rt32;