cachepc-linux

Fork of AMDESE/linux with modifications for CachePC side-channel attack
git clone https://git.sinitax.com/sinitax/cachepc-linux
Log | Files | Refs | README | LICENSE | sfeed.txt

test_encl.lds (774B)

      1OUTPUT_FORMAT(elf64-x86-64)
      2
      3PHDRS
      4{
      5	tcs PT_LOAD;
      6	text PT_LOAD;
      7	data PT_LOAD;
      8}
      9
     10SECTIONS
     11{
     12	. = 0;
     13	.tcs : {
     14		*(.tcs*)
     15	} : tcs
     16
     17	. = ALIGN(4096);
     18	.text : {
     19		*(.text*)
     20		*(.rodata*)
     21		FILL(0xDEADBEEF);
     22		. = ALIGN(4096);
     23	} : text
     24
     25	.data : {
     26		*(.data*)
     27	} : data
     28
     29	/DISCARD/ : {
     30		*(.comment*)
     31		*(.note*)
     32		*(.debug*)
     33		*(.eh_frame*)
     34	}
     35}
     36
     37ASSERT(!DEFINED(.altinstructions), "ALTERNATIVES are not supported in enclaves")
     38ASSERT(!DEFINED(.altinstr_replacement), "ALTERNATIVES are not supported in enclaves")
     39ASSERT(!DEFINED(.discard.retpoline_safe), "RETPOLINE ALTERNATIVES are not supported in enclaves")
     40ASSERT(!DEFINED(.discard.nospec), "RETPOLINE ALTERNATIVES are not supported in enclaves")
     41ASSERT(!DEFINED(.got.plt), "Libcalls are not supported in enclaves")